# Win32::ODBC - Object

## Contents

### Part I

- Module Description
- Business Stuff
  - Copyright Notice
  - Disclaimer
  - GNU General Public License
  - Larry Wall's "Artistic License"
- Version History
  - Author List
- Features/Limits
- Installation Instructions
- Bug Reports
- Latest Versions
- For More Information on Perl

### Part II

- Creating an ODBC Object
- Object Methods
  - Catalog()
  - Connection()
  - Close()
  - Data()
  - DataHash()
  - DataSources()
  - Drivers()
  - DumpError()
  - DumpData()
  - Error()
  - FetchRow()
  - FieldNames()
  - GetConnections()
  - GetDSN()
  - GetStmtCloseType()
  - GetMaxBufSize()
  - MoreResults()
  - new()
  - RowCount()
  - Run()
  - SetMaxBufSize()
  - SetStmtCloseType()
  - Shutdown()
  - Sql()
  - TableList()
- Examples

## Creating an ODBC Object

Your script will need to have the following line:

    	use Win32::ODBC;

Then you will need to create a data connection to your DSN:

    	$Data = new Win32::ODBC("MyDSN");

You shoud check to see if $Data is indeed defined otherwise there has been an error. You can now send SQL queries and retrieve info to your heart's content! See the description of functions below and also test.pl to see how it all works.

Make sure that you close your connection when you are finished:

    	$Data->Close();

## Object Methods

### General Note

All methods assume that you have the line:

    	use Win32::ODBC;

somewhere before the method calls, and that you have an ODBC object called $db which was created using some call similar to:

    	$db = new Win32::ODBC("MyDSN");

See new for more information.

Also, in an effort to keep the examples short, no error checking is done on return values for any calls other than the one being exemplified. You should always check for error conditions in production code.

WARNING: The example code has not yet been tested. This will be fixed ASAP, but be forwarned!

### Methods

Catalog qualifier, owner, name, type
  Retrieves the catalog from the current ODBC object. Returns a four-element array (Qualifier, Owner, Name, Type). Note:All fieldnames are uppercase!

      Example:
      ($qualifier, $owner, $name, $type) = $db->Catalog("", "", "%", "'TABLE'");

Connection
  Returns the object's ODBC connection number.

      Example:
      $cnum = $db->Connection;

Close
  Closes the ODBC connection for this object. It always returns undef.

      Example:
      $db->Close();

Data
Data list
  Retrieve data from previous fetch for a list of field names. In a scalar context it returns all of the field values concatenated together. In an array context, it returns an array of the values, in the order in which they were specified. If no field names are given, all fields are returned in an unspecified order.

      Example:
      $db->Sql("SELECT f1, f2, f3 FROM foo");
      $db->FetchRow();
      ($f1, $f2) = $db->Data("f1", "f2");

      or

      $db->Sql("SELECT * FROM foo");
      $db->FetchRow();
      @values = $db->Data;

  See also: DataHash

DataHash
DataHash list
  Retrieve data from previous fetch for a list of field names. Returns a hash where the field name is the key. If no field names are given, all fields are returned.

      Example:
      $db->Sql("SELECT f1, f2, f3 FROM foo");
      $db->FetchRow();
      %hash = $db->DataHash("f1", "f2");
      print $hash{f1};

      or

      $db->Sql("SELECT * FROM foo");
      $db->FetchRow();
      %hash = $db->DataHash;
      foreach $key (sort(keys %hash)) {
      	print $key, '=', $hash{$key}, "\n";
      }

  See also: Data

DataSources
  Returns an associative array of Data Sources and ODBC remarks in the form of:

      $ArrayName{'DSN'} = Remark

  where DSN is the Data Source Name and Remark is, well, the remark.

      Example:
      %rem = $db->DataSources;
      print LOG qq(Current DSN's Remark: "), %rem{$db->GetDSN}, qq("\n);

Drivers
  Returns an associative array of Drivers and their attributes in the form of:

      $ArrayName{'DRIVER'} = Attrib1;Attrib2;Attrib3;...

  where DRIVER is the ODBC Driver Name and AttribX are the driver-defined attributes.

      Example:
      %attrib = $db->Drivers;
      print LOG qq($driver: $attrib{$driver}\n) foreach $driver (keys %attrib);

DumpError
  Dump to the screen details about the last error condition. This includes error number, error text and the ODBC connection number that caused the error (if there is one). This is used primarily for debugging.

      Example:
      $db = new Win32::ODBC("My DSN");
      if (undef $db){
          Win32::ODBC::DumpError();
      }
      if ($db->Sql("Select * FROM foo")){
          $db->DumpError;
      }

DumpData
  Dump to the screen all field names and the data in all rows of the current dataset. This is used primarily for debugging.

      Example:
      $db->Sql("Select * FROM foo");
      $db->DumpData;

Error
  Returns the last recorded error in the form of an array or string (depending upon the context) containing the error number, error text and the ODBC connection that caused the error (if there is one).

      Example:
      die $db->Error(), qq(\n);

      ($ErrNum, $ErrText, $ErrConn) = $db->Error();

FetchRow
  Fetches the next row of data from the previous specified SQL statement. You would then call Data or DataHash to actually retrieve the individual elements of data. Returns undef if there's an error, TRUE otherwise.

      Example:
      $db->Sql("SELECT * FROM foo");
      $db->FetchRow() || die qq(Fetch error: ), $db->Error(), qq(\n);
      $f1 = $db->Data("f1");

  See also: Sql, Data, DataHash

FieldNames
  Returns a list of field names extracted from the current dataset. This is used mostly for testing/debugging. FieldNames returns the data in an array, with no guarantee of the order of the names.

      Example:
      $db->Sql("SELECT * FROM foo");
      $db->FetchRow();
      foreach $fd ($db->FieldNames()) print qq($fd: "), $db->Data($fd), qq("\n);

GetConnections
  Returns an array of connection numbers for all objects.

      Example:
      @cnums = $db->GetConnections;

GetDSN
GetDSN conn
  Returns the DSN (Data Source Name) or the ODBCDriverConnect string for the connection conn, or the current connection if not specified.

      Example:
      print LOG qq(Current connection: "), $db->GetDSN, qq("\n);

GetMaxBufSize
  Returns the current maximum single field data size, in bytes.

      Example:
      $max = $db->GetMaxBufSize;
      $db->SetMaxBufSize($needed) if ($max < $needed);

  See also: SetMaxBufSize

GetStmtCloseType
  Returns the current ODBC close type setting. This is used mainly for debugging. Type will be one of: SQL_CLOSE, SQL_DROP, SQL_UNBIND, or SQL_RESET_PARAMS. See SetStmtCloseType for more info on what each of the types mean, and how they are used.

      Example:
      $oldct = $db->GetStmtCloseType;
      $db->SetStmtCloseType(SQL_DROP);
      ...
      $db->SetStmtCloseType($oldct);

  See also: SetStmtCloseType

MoreResults
  Sees if more result sets are present and initializes for fetching rows from next result set. You would then call FetchRow to actually fetch the next row of the next result set. Returns undef if there's an error, TRUE otherwise.

      Example:
      $db->Sql("SELECT * FROM foo\n  SELECT * FROM bar");
      $db->FetchRow() || die qq(Fetch error: ), $db->Error(), qq(\n);
      $f1 = $db->Data("f1");
      $db->MoreResults() || die qq(Error checking for more result sets: ), $db->Error(), qq(\n);
      $db->FetchRow() || die qq(Fetch error: ), $db->Error(), qq(\n);
      $f1 = $db->Data("f1");

  See also: Sql, Data

new Win32::ODBC(DSN)
new Win32::ODBC(ODBCDriverConnect)
  Creates a new ODBC object, given a DSN (Data Source Name) or a properly formatted ODBCDriverConnect string. Returns the created ODBC object or undef if there is an error.

      Example:
      $DSN = "MyDSN";
      $db = new Win32::ODBC($DSN);
      die qq(Cannot open new ODBC\n) if ! $db;

      or

      $db = new Win32::ODBC("dsn=FOO;UID=BAR;PWD=FUBAR");
      die qq(Cannot open new ODBC\n) if ! $db;

RowCount
  Returns the number of rows that were affected by the previous SQL command. Note: This does not work on all ODBC connections.

      Example:
      $db->Sql("SELECT * FROM foo");
      print DBG q(# of records: ), $db->RowCount(), qq(\n);

Run stmt
  Submit the SQL statement stmt and print data about it. This is used only in debugging.

      Example:
      $db->Run("SELECT * FROM foo");

  See also: Sql

SetMaxBufSize size
  Sets the maximum buffer size that a single field can allocate when executing a FetchRow. The default limit is 10240 bytes and the absolute maximum is set to 2147483647 bytes. This absolute maximum can be reset by recompiling the module. Returns undef if successful.

      Example:
      $newsize = 20480;
      $rc = $db->SetMaxBufSize($newsize);
      die qq(SetMaxBufSize($newsize) error: ), $db->Error, qq(\n) if ! $rc;

  See also: GetMaxBufSize

SetStmtCloseType type
  Sets the current ODBC close type setting used by the ODBC Manager. This is used mainly for debugging. Normally, when you open a statement handle and perform a query (or whatever) the results are associated with the statement. You need to free the statement in order to execute another query. When you do this, usually the dataset (from the query) is cached. This caching action may be good for speed but could cause some memory problems if your dataset is huge. See the ODBC API call SQLFreeStmt(hstmt, option) for more details. (All of this is handled automatically by the Win32::ODBC package).
  Type will be one of:
  - SQL_CLOSE - just close the statement (use caching)
  - SQL_DROP - close and drop all results (do not use caching)
  - SQL_UNBIND - close and remove bindings to columns (odbc.pll does not bind vars to columns)
  - SQL_RESET_PARAMS - close and reset all of the bound parameters (such as type casting for columns; see SQLFreeStmt())

      Example:
      $oldct = $db->GetStmtCloseType;
      $db->SetStmtCloseType(SQL_DROP);
      ...
      $db->SetStmtCloseType($oldct);

  See also: GetStmtCloseType

ShutDown
  Closes the ODBC connection and print data about it. This is used only in debugging.

      Example:
      $db->Shutdown;

  See also: Close

Sql stmt
  Executes the SQL command stmt. Returns undef on success, SQL error code on failure.

      Example:
      $stmt = "SELECT * FROM foo";
      $rc = $db->Sql($stmt);
      die qq(SQL failed "$stmt": ), $db->Error(), qq(\n) if $rc;

  See also: Error

TableList
TableList qualifier, owner, name, type
  Retrieves the list of table names from the current ODBC object using Catalog. If not specified, qualifier and owner default to "", name defaults to "%", and table defaults to "'TABLE'". TableList returns an array of table names. Note:All fieldnames are uppercase!

      Example:
      @tables = $db->TableList;

  See also: Catalog

## Examples

This page maintined by Joe Casadonte. Please let me if something is wrong or does not make sense. Send these or other comments to: joc@netaxs.com.